cmake_minimum_required(VERSION 3.10)

project(hello_world)

enable_language(CXX)
enable_language(ASM)

# Different linker scripts
set(TARGET_LDSCRIPT_FLASH "${CMAKE_SOURCE_DIR}/rasc_generated/script/fsp.ld")

set(TARGET_SOURCES
    "SDK/FSP/ra/fsp/src/bsp/cmsis/Device/RENESAS/Source/startup.c"
    "SDK/FSP/ra/fsp/src/bsp/cmsis/Device/RENESAS/Source/system.c"
    "SDK/FSP/ra/fsp/src/bsp/mcu/all/bsp_common.c"
    "SDK/FSP/ra/fsp/src/bsp/mcu/all/bsp_clocks.c"
    "SDK/FSP/ra/fsp/src/bsp/mcu/all/bsp_delay.c"
    "SDK/FSP/ra/fsp/src/bsp/mcu/all/bsp_group_irq.c"
    "SDK/FSP/ra/fsp/src/bsp/mcu/all/bsp_guard.c"
    "SDK/FSP/ra/fsp/src/bsp/mcu/all/bsp_io.c"
    "SDK/FSP/ra/fsp/src/bsp/mcu/all/bsp_irq.c"
    "SDK/FSP/ra/fsp/src/bsp/mcu/all/bsp_register_protection.c"
    "SDK/FSP/ra/fsp/src/bsp/mcu/all/bsp_rom_registers.c"
    "SDK/FSP/ra/fsp/src/bsp/mcu/all/bsp_sbrk.c"
    "SDK/FSP/ra/fsp/src/bsp/mcu/all/bsp_security.c"
    "SDK/FSP/ra/fsp/src/r_ioport/r_ioport.c"
    "SDK/FSP/ra/fsp/src/r_sci_uart/r_sci_uart.c"
    "rasc_generated/ra_gen/common_data.c"
    "rasc_generated/ra_gen/hal_data.c"
    "rasc_generated/ra_gen/pin_data.c"
    "rasc_generated/ra_gen/vector_data.c"
    "src/main.c"
    "src/syscalls.c"
    )

set(TARGET_C_DEFINES
    "_RA_CORE=CM33"
    "_RENESAS_RA_"
)

set(TARGET_C_INCLUDES
    "SDK/CMSIS/CMSIS/Core/Include"
    "SDK/FSP/ra/fsp/inc"
    "SDK/FSP/ra/fsp/inc/api"
    "SDK/FSP/ra/fsp/inc/instances"
    "include"
    "rasc_generated/ra_cfg/fsp_cfg"
    "rasc_generated/ra_cfg/fsp_cfg/bsp"
    "rasc_generated/ra_gen"
    )

# Shared libraries linked with application
set(TARGET_LIBS
    "c"
    "m"
    "nosys"
)

# Shared library and linker script search paths
set(TARGET_LIB_DIRECTORIES
    "rasc_generated"
)

# Device specific settings, goes to CFLAGS and LDFLAGS
set(TARGET_CFLAGS_HARDWARE "-mcpu=cortex-m33 -mthumb -mfpu=fpv5-sp-d16 -mfloat-abi=hard")

# Conditional flags
# DEBUG
set(CMAKE_C_FLAGS_DEBUG     "-DDEBUG -O0 -g")
set(CMAKE_CXX_FLAGS_DEBUG   "-DDEBUG -O0 -g")
set(CMAKE_ASM_FLAGS_DEBUG   "-DDEBUG -O0 -g")

# RELEASE
set(CMAKE_C_FLAGS_RELEASE        "-DNDEBUG -O2 -flto")
set(CMAKE_CXX_FLAGS_RELEASE      "-DNDEBUG -O2 -flto")
set(CMAKE_ASM_FLAGS_RELEASE      "-DNDEBUG -O2 -flto")
set(CMAKE_EXE_LINKER_FLAGS_RELEASE "-flto")

# Final compiler flags
set(CMAKE_C_FLAGS          "${CMAKE_C_FLAGS} ${TARGET_CFLAGS_HARDWARE} -Wall -fno-common -fno-builtin -ffreestanding -fdata-sections -ffunction-sections")
set(CMAKE_CXX_FLAGS        "${CMAKE_CXX_FLAGS} ${TARGET_CFLAGS_HARDWARE} -Wall -fno-common -fno-builtin -ffreestanding -fdata-sections -ffunction-sections")
set(CMAKE_ASM_FLAGS        "${CMAKE_ASM_FLAGS} ${CMAKE_C_FLAGS} -x assembler-with-cpp")
set(CMAKE_EXE_LINKER_FLAGS "-specs=nano.specs -specs=nosys.specs -Wl,--gc-sections -Wl,--print-memory-usage -Wl,--no-warn-rwx-segments")

# Shared sources, includes and definitions
add_compile_definitions(${TARGET_C_DEFINES})
include_directories(${TARGET_C_INCLUDES})
link_directories(${TARGET_LIB_DIRECTORIES})
link_libraries(${TARGET_LIBS})

# Main targets are added here

# Create ELF
add_executable("${CMAKE_PROJECT_NAME}_FLASH.elf" ${TARGET_SOURCES})
target_compile_definitions("${CMAKE_PROJECT_NAME}_FLASH.elf"
    PRIVATE ${TARGET_C_DEFINES_XIP}
)
target_link_options("${CMAKE_PROJECT_NAME}_FLASH.elf"
    PRIVATE "-T${TARGET_LDSCRIPT_FLASH}"
    PRIVATE "-Wl,--Map=${CMAKE_PROJECT_NAME}_FLASH.map"
)
set_property(TARGET "${CMAKE_PROJECT_NAME}_FLASH.elf" APPEND
    PROPERTY ADDITIONAL_CLEAN_FILES "${CMAKE_PROJECT_NAME}_FLASH.map"
)
add_custom_command(OUTPUT "${CMAKE_PROJECT_NAME}_FLASH.hex"
    COMMAND ${CMAKE_OBJCOPY} "-O" "ihex" "${CMAKE_PROJECT_NAME}_FLASH.elf" "${CMAKE_PROJECT_NAME}_FLASH.hex"
    DEPENDS "${CMAKE_PROJECT_NAME}_FLASH.elf"
)
add_custom_target("${CMAKE_PROJECT_NAME}_FLASH_HEX" DEPENDS "${CMAKE_PROJECT_NAME}_FLASH.hex")