cmake_minimum_required(VERSION 3.10)

project(STM32H750VB_DAC_CS4344_A1)

enable_language(CXX)
enable_language(ASM)

# Extra CFlags
set(TARGET_CFLAGS_EXTRA   "")
set(TARGET_CXXFLAGS_EXTRA "")
set(TARGET_LDFLAGS_EXTRA  "-Wl,--print-memory-usage")

# Different linker scripts
set(TARGET_LDSCRIPT_FLASH "${CMAKE_SOURCE_DIR}/STM32H750VBTx_FLASH.ld")
set(TARGET_LDSCRIPT_RAM   "${CMAKE_SOURCE_DIR}/STM32H750VBTx_RAM.ld")

# Copy them from Makefile
set(TARGET_C_SOURCES
    "Core/Src/audio/audio_clocksel.c"
    "Core/Src/audio/audio_amp.c"
    "Core/Src/audio/impl/tpa6130a2_impl.c"
    "Core/Src/azrtos/usbx_dcd/ux_dcd_stm32_callback.c"
    "Core/Src/azrtos/usbx_dcd/ux_dcd_stm32_endpoint_create.c"
    "Core/Src/azrtos/usbx_dcd/ux_dcd_stm32_endpoint_destroy.c"
    "Core/Src/azrtos/usbx_dcd/ux_dcd_stm32_endpoint_reset.c"
    "Core/Src/azrtos/usbx_dcd/ux_dcd_stm32_endpoint_stall.c"
    "Core/Src/azrtos/usbx_dcd/ux_dcd_stm32_endpoint_status.c"
    "Core/Src/azrtos/usbx_dcd/ux_dcd_stm32_frame_number_get.c"
    "Core/Src/azrtos/usbx_dcd/ux_dcd_stm32_function.c"
    "Core/Src/azrtos/usbx_dcd/ux_dcd_stm32_initialize_complete.c"
    "Core/Src/azrtos/usbx_dcd/ux_dcd_stm32_initialize.c"
    "Core/Src/azrtos/usbx_dcd/ux_dcd_stm32_interrupt_handler.c"
    "Core/Src/azrtos/usbx_dcd/ux_dcd_stm32_transfer_request.c"
    "Core/Src/azrtos/usbx_dcd/ux_dcd_stm32_uninitialize.c"
    "Core/Src/main.c"
    "Core/Src/stm32h7xx_it.c"
    "Core/Src/stm32h7xx_hal_msp.c"
    "Core/Src/stm32h7xx_hal_timebase_tim.c"
    "Core/Src/system_stm32h7xx.c"
    "Core/Src/usbd_uac_process.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_cortex.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_dma.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_dma_ex.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_exti.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_flash.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_flash_ex.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_gpio.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_hsem.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_i2c.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_i2c_ex.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_mdma.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_pcd.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_pcd_ex.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_pwr.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_pwr_ex.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_qspi.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_ramecc.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_rcc.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_rcc_ex.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_rng.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_rng_ex.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_rtc.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_rtc_ex.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_sai.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_sai_ex.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_sd.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_sd_ex.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_spi.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_spi_ex.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_tim.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_tim_ex.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_uart.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_hal_uart_ex.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_ll_sdmmc.c"
    "Drivers/STM32H7xx_HAL_Driver/Src/stm32h7xx_ll_usb.c"
)

# Copy them from Makefile
set(TARGET_ASM_SOURCES
    "startup_stm32h750xx.s"
)

# Copy them from Makefile
set(TARGET_C_DEFINES
    "STM32H750xx"
    "USE_HAL_DRIVER"
)

set(TARGET_C_DEFINES_RAM
    "DATA_IN_D2_SRAM"
    "VECT_TAB_SRAM"
    "USER_VECT_TAB_ADDRESS"
)

# Copy them from Makefile
set(TARGET_C_INCLUDES
    "Core/Inc"
    "Core/Inc/azrtos/usbx_dcd"
    "Drivers/STM32H7xx_HAL_Driver/Inc"
    "Drivers/STM32H7xx_HAL_Driver/Inc/Legacy"
    "Drivers/CMSIS/Device/ST/STM32H7xx/Include"
    "Drivers/CMSIS/Include"
)

# Shared libraries linked with application
set(TARGET_LIBS
    "tpa6130"
    "threadx"
    "filex"
    "netxduo"
    "usbx"
)

# Shared library and linker script search paths
set(TARGET_LIB_DIRECTORIES
)

# Device specific settings, goes to CFLAGS and LDFLAGS
set(TARGET_CFLAGS_HARDWARE "-mcpu=cortex-m7 -mfpu=fpv5-d16 -mfloat-abi=hard -mthumb")

# Conditional flags
# DEBUG
set(CMAKE_C_FLAGS_DEBUG     "-DDEBUG -Og -g")
set(CMAKE_CXX_FLAGS_DEBUG   "-DDEBUG -Og -g")
set(CMAKE_ASM_FLAGS_DEBUG   "-DDEBUG -Og -g")

# RELEASE
set(CMAKE_C_FLAGS_RELEASE        "-DNDEBUG -O2 -flto")
set(CMAKE_CXX_FLAGS_RELEASE      "-DNDEBUG -O2 -flto")
set(CMAKE_ASM_FLAGS_RELEASE      "-DNDEBUG -O2 -flto")
set(CMAKE_EXE_LINKER_FLAGS_RELEASE "-flto")

# Final compiler flags
set(CMAKE_C_FLAGS          "${CMAKE_C_FLAGS} ${TARGET_CFLAGS_HARDWARE} ${TARGET_CFLAGS_EXTRA} -Wall -fdata-sections -ffunction-sections")
set(CMAKE_CXX_FLAGS        "${CMAKE_CXX_FLAGS} ${TARGET_CFLAGS_HARDWARE} ${TARGET_CXXFLAGS_EXTRA} -Wall -fdata-sections -ffunction-sections")
set(CMAKE_ASM_FLAGS        "${CMAKE_ASM_FLAGS} ${CMAKE_C_FLAGS} -x assembler-with-cpp")
set(CMAKE_EXE_LINKER_FLAGS "-specs=nano.specs -Wl,--gc-sections -lc -lm -lnosys ${TARGET_LDFLAGS_EXTRA}")

# Include sub directories here
add_subdirectory(lib/tpa6130a2)

set(THREADX_ARCH "cortex_m7")
set(THREADX_TOOLCHAIN "gnu")
set(THREADX_CUSTOM_PORT "${CMAKE_CURRENT_SOURCE_DIR}/Middlewares/Third_Party/azrtos/cubemx_port/cortex_m7/gnu" )
set(TX_USER_FILE "${CMAKE_CURRENT_SOURCE_DIR}/Core/Inc/azrtos/tx_user.h")

add_subdirectory(Middlewares/Third_Party/azrtos/threadx)
add_subdirectory(Middlewares/Third_Party/azrtos/filex)
add_subdirectory(Middlewares/Third_Party/azrtos/netxduo)
add_subdirectory(Middlewares/Third_Party/azrtos/usbx)

# Shared sources, includes and definitions
add_compile_definitions(${TARGET_C_DEFINES})
include_directories(${TARGET_C_INCLUDES})
link_directories(${TARGET_LIB_DIRECTORIES})
link_libraries(${TARGET_LIBS})

# Main targets are added here

# **** Internal Flash ****

# Create ELF
add_executable("${CMAKE_PROJECT_NAME}_FLASH.elf" ${TARGET_C_SOURCES} ${TARGET_ASM_SOURCES})
target_link_options("${CMAKE_PROJECT_NAME}_FLASH.elf"
    PRIVATE "-T${TARGET_LDSCRIPT_FLASH}"
    PRIVATE "-Wl,-Map=${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_PROJECT_NAME}_FLASH.map,--cref"
)

add_custom_command(OUTPUT "${CMAKE_PROJECT_NAME}_FLASH.hex"
    COMMAND ${CMAKE_OBJCOPY} "-O" "ihex" "${CMAKE_PROJECT_NAME}_FLASH.elf" "${CMAKE_PROJECT_NAME}_FLASH.hex"
    DEPENDS "${CMAKE_PROJECT_NAME}_FLASH.elf"
)
add_custom_target("${CMAKE_PROJECT_NAME}_FLASH_HEX" DEPENDS "${CMAKE_PROJECT_NAME}_FLASH.hex")

# **** All In SRAM ****

# Create ELF
add_executable("${CMAKE_PROJECT_NAME}_RAM.elf" ${TARGET_C_SOURCES} ${TARGET_ASM_SOURCES})
target_link_options("${CMAKE_PROJECT_NAME}_RAM.elf"
    PRIVATE "-T${TARGET_LDSCRIPT_RAM}"
    PRIVATE "-Wl,-Map=${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_PROJECT_NAME}_RAM.map,--cref"
)
target_compile_definitions("${CMAKE_PROJECT_NAME}_RAM.elf" PRIVATE ${TARGET_C_DEFINES_RAM})

add_custom_command(OUTPUT "${CMAKE_PROJECT_NAME}_RAM.hex"
    COMMAND ${CMAKE_OBJCOPY} "-O" "ihex" "${CMAKE_PROJECT_NAME}_RAM.elf" "${CMAKE_PROJECT_NAME}_RAM.hex"
    DEPENDS "${CMAKE_PROJECT_NAME}_RAM.elf"
)
add_custom_target("${CMAKE_PROJECT_NAME}_RAM_HEX" DEPENDS "${CMAKE_PROJECT_NAME}_RAM.hex")