cmake_minimum_required(VERSION 3.10)

project(STM32H750_LCD)

enable_language(CXX)
enable_language(ASM)

# Device specific settings, goes to CFLAGS and LDFLAGS
set(CFLAGS_HARDWARE "-mcpu=cortex-m7 -mfpu=fpv5-d16 -mfloat-abi=hard -mthumb")

# Extra CFlags
set(CFLAGS_EXTRA "-Og")
set(LDFLAGS_EXTRA "-Wl,--print-memory-usage")

# Different linker scripts
set(LDSCRIPT_FLASH "${CMAKE_SOURCE_DIR}/STM32H750VBTx_FLASH.ld")
set(LDSCRIPT_QSPI_FLASH "${CMAKE_SOURCE_DIR}/STM32H750VBTx_QSPI_FLASH.ld")
set(LDSCRIPT_RAM "${CMAKE_SOURCE_DIR}/STM32H750VBTx_RAM.ld")

# Copy them from Makefile
set(C_SOURCES
    "Core/Src/main.c"
    "Core/Src/stm32h7xx_it.c"
    "Core/Src/stm32h7xx_hal_msp.c"
    "Core/Src/otm8009a_lcd.c"
    "Core/Src/otm_lcd_impl.c"
    "Core/Src/user_tasks.c"
    "Core/Src/user_task_lvgl.c"
    "Core/Src/user_task_hello.c"
    "Core/Src/otm_lcd_lvgl_impl.c"
    "Core/Src/kururin_pa.c"
    "Core/Src/system_stm32h7xx.c"
    "Core/Src/freertos.c"
    "Core/Src/stm32h7xx_hal_timebase_tim.c"
    "FATFS/App/fatfs.c"
    "FATFS/Target/bsp_driver_sd.c"
    "FATFS/Target/sd_diskio.c"
    "FATFS/Target/fatfs_platform.c"
    "Middlewares/Third_Party/FatFs/src/diskio.c"
    "Middlewares/Third_Party/FatFs/src/ff.c"
    "Middlewares/Third_Party/FatFs/src/ff_gen_drv.c"
    "Middlewares/Third_Party/FatFs/src/option/syscall.c"
    "Middlewares/Third_Party/FatFs/src/option/cc932.c"
)

# Copy them from Makefile
set(ASM_SOURCES
    "startup_stm32h750xx.s"
)

set(C_LIBRARIES
    "lvgl"
    "rtos"
    "stm32_hal_driver"
)

# Copy them from Makefile
set(C_DEFINES
    "LV_LVGL_H_INCLUDE_SIMPLE"
    "STM32H750xx"
    "USE_HAL_DRIVER"
    "USE_FULL_LL_DRIVER"
)

# Copy them from Makefile
set(C_INCLUDES
    "Core/Inc"
    "Drivers/STM32H7xx_HAL_Driver/Inc"
    "Drivers/STM32H7xx_HAL_Driver/Inc/Legacy"
    "Drivers/CMSIS/Device/ST/STM32H7xx/Include"
    "Drivers/CMSIS/Include"
    "Middlewares/Third_Party/FreeRTOS/Source/include"
    "Middlewares/Third_Party/FreeRTOS/Source/CMSIS_RTOS_V2"
    "Middlewares/Third_Party/FreeRTOS/Source/portable/GCC/ARM_CM4F"
    "Middlewares/Third_Party/LittleVGL"
    "FATFS/Target"
    "FATFS/App"
    "Middlewares/Third_Party/FatFs/src"
)

# Final compiler flags
set(CMAKE_C_FLAGS "${CFLAGS_HARDWARE} ${CFLAGS_EXTRA} -Wall -fdata-sections -ffunction-sections")
set(CMAKE_CXX_FLAGS "${CFLAGS_HARDWARE} ${CFLAGS_EXTRA} -Wall -fdata-sections -ffunction-sections")
set(CMAKE_ASM_FLAGS "${CMAKE_C_FLAGS} -x assembler-with-cpp")
set(CMAKE_EXE_LINKER_FLAGS "${CFLAGS_HARDWARE} -specs=nano.specs -Wl,--gc-sections -lc -lm -lnosys ${LDFLAGS_EXTRA}")

add_subdirectory(Drivers)
add_subdirectory(Middlewares)

# Main targets are added here

# **** Internal Flash ****

# Create ELF
add_executable("${CMAKE_PROJECT_NAME}_FLASH.elf" ${C_SOURCES} ${ASM_SOURCES})
target_compile_definitions("${CMAKE_PROJECT_NAME}_FLASH.elf" PRIVATE ${C_DEFINES})
target_include_directories("${CMAKE_PROJECT_NAME}_FLASH.elf" PRIVATE ${C_INCLUDES})
target_link_libraries("${CMAKE_PROJECT_NAME}_FLASH.elf" ${C_LIBRARIES})

target_link_options("${CMAKE_PROJECT_NAME}_FLASH.elf"
    PRIVATE "-T${LDSCRIPT_FLASH}"
    PRIVATE "-Wl,-Map=${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_PROJECT_NAME}_FLASH.map,--cref"
)

target_compile_options("${CMAKE_PROJECT_NAME}_FLASH.elf"
    PRIVATE "${FINAL_C_FLAGS}"
)

add_custom_command(OUTPUT "${CMAKE_PROJECT_NAME}_FLASH.hex"
    COMMAND ${CMAKE_OBJCOPY} "-O" "ihex" "${CMAKE_PROJECT_NAME}_FLASH.elf" "${CMAKE_PROJECT_NAME}_FLASH.hex"
    DEPENDS "${CMAKE_PROJECT_NAME}_FLASH.elf"
)
add_custom_target("${CMAKE_PROJECT_NAME}_FLASH_HEX"
    DEPENDS "${CMAKE_PROJECT_NAME}_FLASH.hex"
)

# **** All In SRAM ****

# Create ELF
add_executable("${CMAKE_PROJECT_NAME}_RAM.elf" ${C_SOURCES} ${ASM_SOURCES})
target_compile_definitions("${CMAKE_PROJECT_NAME}_RAM.elf" PRIVATE ${C_DEFINES})
target_include_directories("${CMAKE_PROJECT_NAME}_RAM.elf" PRIVATE ${C_INCLUDES})
target_link_libraries("${CMAKE_PROJECT_NAME}_RAM.elf" ${C_LIBRARIES})

# Linker script and Map files
target_link_options("${CMAKE_PROJECT_NAME}_RAM.elf"
    PRIVATE "-T${LDSCRIPT_RAM}"
    PRIVATE "-Wl,-Map=${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_PROJECT_NAME}_RAM.map,--cref"
)

# Additional defines
target_compile_definitions("${CMAKE_PROJECT_NAME}_RAM.elf"
    PRIVATE "VECT_TAB_SRAM"
    PRIVATE "DATA_IN_D2_SRAM"
)

add_custom_command(OUTPUT "${CMAKE_PROJECT_NAME}_RAM.hex"
    COMMAND ${CMAKE_OBJCOPY} "-O" "ihex" "${CMAKE_PROJECT_NAME}_RAM.elf" "${CMAKE_PROJECT_NAME}_RAM.hex"
    DEPENDS "${CMAKE_PROJECT_NAME}_RAM.elf"
)

add_custom_target("${CMAKE_PROJECT_NAME}_RAM_HEX"
    DEPENDS "${CMAKE_PROJECT_NAME}_RAM.hex"
)

# **** QUADSPI XIP ****

# Create ELF
add_executable("${CMAKE_PROJECT_NAME}_QSPI_FLASH.elf" ${C_SOURCES} ${ASM_SOURCES})
target_compile_definitions("${CMAKE_PROJECT_NAME}_QSPI_FLASH.elf" PRIVATE ${C_DEFINES})
target_include_directories("${CMAKE_PROJECT_NAME}_QSPI_FLASH.elf" PRIVATE ${C_INCLUDES})
target_link_libraries("${CMAKE_PROJECT_NAME}_QSPI_FLASH.elf" ${C_LIBRARIES})

# Linker script and Map files
target_link_options("${CMAKE_PROJECT_NAME}_QSPI_FLASH.elf"
    PRIVATE "-T${LDSCRIPT_QSPI_FLASH}"
    PRIVATE "-Wl,-Map=${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_PROJECT_NAME}_QSPI_FLASH.map,--cref"
)

# Additional defines
target_compile_definitions("${CMAKE_PROJECT_NAME}_QSPI_FLASH.elf"
    PRIVATE "FLASH_XIP_BASE=0x90000000"
)

add_custom_command(OUTPUT "${CMAKE_PROJECT_NAME}_QSPI_FLASH.hex"
    COMMAND ${CMAKE_OBJCOPY} "-O" "ihex" "${CMAKE_PROJECT_NAME}_QSPI_FLASH.elf" "${CMAKE_PROJECT_NAME}_QSPI_FLASH.hex"
    DEPENDS "${CMAKE_PROJECT_NAME}_QSPI_FLASH.elf"
)

add_custom_target("${CMAKE_PROJECT_NAME}_QSPI_FLASH_HEX"
    DEPENDS "${CMAKE_PROJECT_NAME}_QSPI_FLASH.hex"
)

add_custom_command(OUTPUT "${CMAKE_PROJECT_NAME}_QSPI_FLASH.bin"
    COMMAND ${CMAKE_OBJCOPY} "-O" "binary" "${CMAKE_PROJECT_NAME}_QSPI_FLASH.elf" "${CMAKE_PROJECT_NAME}_QSPI_FLASH.bin"
    DEPENDS "${CMAKE_PROJECT_NAME}_QSPI_FLASH.elf"
)

add_custom_target("${CMAKE_PROJECT_NAME}_QSPI_FLASH_BIN"
    DEPENDS "${CMAKE_PROJECT_NAME}_QSPI_FLASH.bin"
)