cmake_minimum_required(VERSION 3.10)

project(t113i_c906_freertos)

enable_language(CXX)
enable_language(ASM)

# Different linker scripts
set(TARGET_LDSCRIPT_FLASH "${CMAKE_SOURCE_DIR}/GCC/T113i_RAM.ld")

set(TARGET_SOURCES
    "startup/c906_it.c"
    "startup/resource_table.c"
    "startup/startup_c906.S"
    "startup/system_c906.c"
    "src/freertos/port.c"
    "src/main.c"
    "src/tasks/app_task_hello.c"
    "src/tasks/app_tasks.c"
)

set(TARGET_C_DEFINES
)

set(TARGET_C_INCLUDES
    "include"
)

# Shared libraries linked with application
set(TARGET_LIBS
    "freertos_kernel"
    "c"
    "m"
    "nosys"
)

# Shared library and linker script search paths
set(TARGET_LIB_DIRECTORIES
)

# Conditional flags
# DEBUG
set(CMAKE_C_FLAGS_DEBUG     "-DDEBUG -O0 -g")
set(CMAKE_CXX_FLAGS_DEBUG   "-DDEBUG -O0 -g")
set(CMAKE_ASM_FLAGS_DEBUG   "-DDEBUG -O0 -g")

# RELEASE
set(CMAKE_C_FLAGS_RELEASE        "-DNDEBUG -O2")
set(CMAKE_CXX_FLAGS_RELEASE      "-DNDEBUG -O2")
set(CMAKE_ASM_FLAGS_RELEASE      "-DNDEBUG -O2")
set(CMAKE_EXE_LINKER_FLAGS_RELEASE "")

# Final compiler flags
set(CMAKE_C_FLAGS          "${CMAKE_C_FLAGS} -Wall -fno-common -fno-builtin -ffreestanding -fdata-sections -ffunction-sections")
set(CMAKE_CXX_FLAGS        "${CMAKE_CXX_FLAGS} -Wall -fno-common -fno-builtin -ffreestanding -fdata-sections -ffunction-sections")
set(CMAKE_ASM_FLAGS        "${CMAKE_C_FLAGS} -x assembler-with-cpp")
set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--gc-sections")

add_library(freertos_config INTERFACE)
target_include_directories(freertos_config SYSTEM INTERFACE ${CMAKE_CURRENT_SOURCE_DIR}/include)
set(FREERTOS_PORT GCC_RISC_V_GENERIC CACHE STRING "")
set(FREERTOS_RISCV_EXTENSION RV64GCV_XuanTie_C906 CACHE STRING "")
set(FREERTOS_HEAP "4" CACHE STRING "")
add_subdirectory(lib/freertos)

# Shared sources, includes and definitions
add_compile_definitions(${TARGET_C_DEFINES})
include_directories(${TARGET_C_INCLUDES})
link_directories(${TARGET_LIB_DIRECTORIES})
link_libraries(${TARGET_LIBS})

# Main targets are added here

# Create ELF
add_executable("${CMAKE_PROJECT_NAME}_FLASH.elf" ${TARGET_SOURCES})
target_compile_definitions("${CMAKE_PROJECT_NAME}_FLASH.elf"
    PRIVATE ${TARGET_C_DEFINES_XIP}
    )
target_link_options("${CMAKE_PROJECT_NAME}_FLASH.elf"
    PRIVATE "-T${TARGET_LDSCRIPT_FLASH}"
    PRIVATE "-Wl,--Map=${CMAKE_PROJECT_NAME}_FLASH.map"
    )
set_property(TARGET "${CMAKE_PROJECT_NAME}_FLASH.elf" APPEND
    PROPERTY ADDITIONAL_CLEAN_FILES "${CMAKE_PROJECT_NAME}_FLASH.map"
    )
add_custom_command(OUTPUT "${CMAKE_PROJECT_NAME}_FLASH.hex"
    COMMAND ${CMAKE_OBJCOPY} "-O" "ihex" "${CMAKE_PROJECT_NAME}_FLASH.elf" "${CMAKE_PROJECT_NAME}_FLASH.hex"
    DEPENDS "${CMAKE_PROJECT_NAME}_FLASH.elf"
    )
add_custom_target("${CMAKE_PROJECT_NAME}_FLASH_HEX" DEPENDS "${CMAKE_PROJECT_NAME}_FLASH.hex")
if(DEFINED TARGET_TOOLCHAIN_SIZE)
    add_custom_command(TARGET "${CMAKE_PROJECT_NAME}_FLASH.elf" POST_BUILD
        COMMAND ${TARGET_TOOLCHAIN_SIZE} "${CMAKE_PROJECT_NAME}_FLASH.elf"
        )
endif()