# SPDX-License-Identifier: MIT

cmake_minimum_required(VERSION 3.10)

project(ch32v307_template)

enable_language(CXX)
enable_language(ASM)

# Extra CFlags
set(TARGET_CFLAGS_EXTRA   "")
set(TARGET_CXXFLAGS_EXTRA "")
set(TARGET_LDFLAGS_EXTRA  "-Wl,--print-memory-usage")

# Different linker scripts
set(TARGET_LDSCRIPT_FLASH "${CMAKE_SOURCE_DIR}/BSP/Ld/Link.ld")

# Copy them from Makefile
set(TARGET_C_SOURCES
    "BSP/Core/core_riscv.c"
    "BSP/Debug/debug.c"
    "BSP/Peripheral/src/ch32v30x_adc.c"
    "BSP/Peripheral/src/ch32v30x_bkp.c"
    "BSP/Peripheral/src/ch32v30x_can.c"
    "BSP/Peripheral/src/ch32v30x_crc.c"
    "BSP/Peripheral/src/ch32v30x_dac.c"
    "BSP/Peripheral/src/ch32v30x_dbgmcu.c"
    "BSP/Peripheral/src/ch32v30x_dma.c"
    "BSP/Peripheral/src/ch32v30x_dvp.c"
    "BSP/Peripheral/src/ch32v30x_eth.c"
    "BSP/Peripheral/src/ch32v30x_exti.c"
    "BSP/Peripheral/src/ch32v30x_flash.c"
    "BSP/Peripheral/src/ch32v30x_fsmc.c"
    "BSP/Peripheral/src/ch32v30x_gpio.c"
    "BSP/Peripheral/src/ch32v30x_i2c.c"
    "BSP/Peripheral/src/ch32v30x_iwdg.c"
    "BSP/Peripheral/src/ch32v30x_misc.c"
    "BSP/Peripheral/src/ch32v30x_opa.c"
    "BSP/Peripheral/src/ch32v30x_pwr.c"
    "BSP/Peripheral/src/ch32v30x_rcc.c"
    "BSP/Peripheral/src/ch32v30x_rng.c"
    "BSP/Peripheral/src/ch32v30x_rtc.c"
    "BSP/Peripheral/src/ch32v30x_sdio.c"
    "BSP/Peripheral/src/ch32v30x_spi.c"
    "BSP/Peripheral/src/ch32v30x_tim.c"
    "BSP/Peripheral/src/ch32v30x_usart.c"
    "BSP/Peripheral/src/ch32v30x_wwdg.c"
    "src/board.c"
    "src/ch32v30x_it.c"
    "src/main.c"
    "src/system_ch32v30x.c"
)

# Copy them from Makefile
set(TARGET_ASM_SOURCES
    "BSP/Startup/startup_ch32v30x_D8C.S"
)

# Copy them from Makefile
set(TARGET_C_DEFINES
)

# Copy them from Makefile
set(TARGET_C_INCLUDES
    "BSP/Core"
    "BSP/Debug"
    "BSP/Peripheral/inc"
    "include"
)

# Shared libraries linked with application
set(TARGET_LIBS
)

# Shared library and linker script search paths
set(TARGET_LIB_DIRECTORIES
)

# Device specific settings, goes to CFLAGS and LDFLAGS
set(TARGET_CFLAGS_HARDWARE "-march=rv32imafc -mabi=ilp32f")

# Conditional flags
# DEBUG
set(CMAKE_C_FLAGS_DEBUG     "-DDEBUG -Og -g")
set(CMAKE_CXX_FLAGS_DEBUG   "-DDEBUG -Og -g")
set(CMAKE_ASM_FLAGS_DEBUG   "-DDEBUG -Og -g")

# RELEASE
set(CMAKE_C_FLAGS_RELEASE        "-DNDEBUG -O2 -flto")
set(CMAKE_CXX_FLAGS_RELEASE      "-DNDEBUG -O2 -flto")
set(CMAKE_ASM_FLAGS_RELEASE      "-DNDEBUG -O2 -flto")
set(CMAKE_EXE_LINKER_FLAGS_RELEASE "-flto")

# Final compiler flags
set(CMAKE_C_FLAGS          "${CMAKE_C_FLAGS} ${TARGET_CFLAGS_HARDWARE} ${TARGET_CFLAGS_EXTRA} -Wall -fdata-sections -ffunction-sections")
set(CMAKE_CXX_FLAGS        "${CMAKE_CXX_FLAGS} ${TARGET_CFLAGS_HARDWARE} ${TARGET_CXXFLAGS_EXTRA} -Wall -fdata-sections -ffunction-sections")
set(CMAKE_ASM_FLAGS        "${CMAKE_ASM_FLAGS} ${CMAKE_C_FLAGS} -x assembler-with-cpp")
set(CMAKE_EXE_LINKER_FLAGS "-Wl,--gc-sections -nostdlib -nostartfiles ${TARGET_LDFLAGS_EXTRA}")

# Include sub directories here

# Shared sources, includes and definitions
add_compile_definitions(${TARGET_C_DEFINES})
include_directories(${TARGET_C_INCLUDES})
link_directories(${TARGET_LIB_DIRECTORIES})
link_libraries(${TARGET_LIBS})

# Main targets are added here

# **** Internal Flash ****

# Create ELF
add_executable("${CMAKE_PROJECT_NAME}_FLASH.elf" ${TARGET_C_SOURCES} ${TARGET_ASM_SOURCES})
target_link_options("${CMAKE_PROJECT_NAME}_FLASH.elf"
    PRIVATE "-T${TARGET_LDSCRIPT_FLASH}"
    PRIVATE "-Wl,-Map=${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_PROJECT_NAME}_FLASH.map,--cref"
)
target_link_libraries("${CMAKE_PROJECT_NAME}_FLASH.elf"
    PRIVATE "-lnosys -lc -lgcc -lnosys"
)

add_custom_command(OUTPUT "${CMAKE_PROJECT_NAME}_FLASH.hex"
    COMMAND ${CMAKE_OBJCOPY} "-O" "ihex" "${CMAKE_PROJECT_NAME}_FLASH.elf" "${CMAKE_PROJECT_NAME}_FLASH.hex"
    DEPENDS "${CMAKE_PROJECT_NAME}_FLASH.elf"
)
add_custom_target("${CMAKE_PROJECT_NAME}_FLASH_HEX" DEPENDS "${CMAKE_PROJECT_NAME}_FLASH.hex")

# **** Cortex-M0 does not support SCB->VTOR configuration, so RAM debug is not possible. ****